JRA IPAT操作関係? RSSフィード
 


挨拶・自己紹介:失敗続きのAB型の変わり者 三流プログラマー Ken3です。
(※[三流君 三流プログラマーとは?自己紹介や経歴ほか])

Ken3のひとりグループです
・[ken3独りグループのトップページ]へ戻る
・独り言の[掲示板を覗く]
・勝手に作成した[キーワード一覧]を見る
・いつまでも[ken3memo下書き日記]を見る
(一人寂しくグループウェアを使っていたり....(笑))


リスト表示 | ツリー表示

1ken3memoken3memo   JRA IPAT操作関係?

最近質問が多い、JRA IPATの操作関係をまとめてみる予定・・・

1.IPAT ログイン

http://www.ipat.jra.go.jp/ に ログインする

ログイン処理

ログイン処理 解説とソースコード

↑を見てください。


2.入金処理

投票する前に 軍資金を入金しないといけないので、

入金処理 解説とソースコード

を作成してみました。


3.情報収集

分析用の情報を集める

単勝オッズの取得 解説とソースコード

↑まずは基本の単勝オッズ?の取得


4.分析・買う目を決める

上の3で集めた情報を使用して、買うレース、馬を決める


5.投票を行う

勝ち馬投票券の購入


6.結果の確認(3や4に含んでもいいけど)

結果によって、やめるか?、続けてドツボにハマるか判断する


7.自動実行、繰り返す

1~6を自動で繰り返す。そんなプログラムをみんな夢見てチャレンジする・・・

返信2012/04/15 11:39:21

2ken3memoken3memo   1  1.ログイン処理

1.IPAT ログイン

http://www.ipat.jra.go.jp/ に ログインする

まず、ここからかなぁ。


完成したソース

xxxx.vbs など、.vbsで保存して、使ってみてください。

'頭で固定値をセットする 自分の番号をセットする。
strINET_ID  = "S999999PC"   'INET-ID
strP_ARS    = "0000"      'P-ARS
strK_No     = "60099999"  '加入者番号
strPassword = "1234"      '暗証番号、あまり保存したくないけど

'パスワード保存したくない人向け、頭で入力させる
If strPassword = "" Then
    strPassword = InputBox("暗証番号を入れてください")
End If


'IEの起動

    Dim objNewIE  '新しいIEのオブジェクト

    Dim objIE  '変数を定義します。
    Set objIE = WScript.CreateObject("InternetExplorer.Application", "IEMain_") 'オブジェクト作成
    objIE.Visible = True      '可視、Trueで見えるようにします。
    
'処理したいページを表示します。
    objIE.Navigate "http://www.ipat.jra.go.jp/"

'ページの表示完了を待ちます。
    While objIE.ReadyState <> 4 Or objIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend

'INET-ID(name=inetid)にセットする。
    Set objINETID = objIE.Document.getElementsByName("inetid") '変数に一度セットする

    If objINETID.Length = 0 Then  '.Lengthで 取得したエレメントの数がわかります
        '終了処理/エラー処理 0の時は見つからなかったので 
        Msgbox "時間外です。 時間と表示されている場所を確認してください"
        WScript.Quit   'スクリプトを途中で抜ける
    End If

    objINETID(0).Value = strINET_ID   'データをセットする
    Set objINETID = Nothing  'オブジェクト変数解放

'ログインボタンを探して押す
    'Aのタグを集める
    Set objA = objIE.Document.getElementsByTagName("A")

    'ループで頭からタイトルがログインを探す
    For n = 0 To objA.Length - 1
        If objA(n).Title = "ログイン" then
            objA(n).Click  '見つけたAタグのオブジェクトをクリック
            Exit For
        End If
    Next

    Set objA = Nothing  'オブジェクト変数解放

'手抜きで、ログイン判断で5秒待つ?
WScript.Sleep  5000  '5秒待つ 1000で1秒

'シェルのオブジェクトを作成後、一番後ろを取り出す
Set objShell = WScript.CreateObject("Shell.Application")
Set objNewIE = objShell.Windows(objShell.Windows.Count - 1) '最後のウインドウと決めつけセット
Set objShell = Nothing  'オブジェクト変数解放

'ページの表示完了を待ちます。
    While objNewIE.ReadyState <> 4 Or objNewIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend

'新しく開いたIEに値をセットする
    'エラー画面か?項目名iの数でチェックする
    Set objI = objNewIE.Document.getElementsByName("i") '変数に一度セットする
    If objI.Length = 0 Then  '.Lengthで 取得したエレメントの数がわかります
        '終了処理/エラー処理 0の時は見つからなかったので 
        Msgbox "INET-IDがエラーです確認してください。"
        objNewIE.Quit  '新しく開いたIEを閉じる
        objIE.Quit     '元のIEも閉じる
        WScript.Quit   'スクリプトを途中で強制終了
    End If
    Set objI = Nothing

    '名前が i,p,r にそれぞれセットする。 セットする場所が objNewIEに注意
    objNewIE.Document.forms("FORM1").Item("i").Value = strK_No '加入者番号
    objNewIE.Document.forms("FORM2").Item("p").Value = strPassword '暗証番号
    objNewIE.Document.forms("FORM3").Item("r").Value = strP_ARS  'P-ARS
    '↑同じ名称が使われているので、forms("FORM1"),2,3を指定しました。

'IPATメニューへ を クリックする
    'Aのタグを集める
    Set objA = objNewIE.Document.getElementsByTagName("A")

    'ループで頭からタイトルがログインを探す
    For n = 0 To objA.Length - 1
        If objA(n).Title = "IPATメニューへ" then
            objA(n).Click  '見つけたAタグのオブジェクトをクリック
            Exit For
        End If
    Next

    Set objA = Nothing  'オブジェクト変数解放

msgbox "ログイン スクリプト 終了 "

'ここから、データ取得や投票を行う、そんなスクリプトを書く

WScript.Quit   'スクリプトを終了

'------------------------------------------------
'元IE(のイベント処理)
'スクリプトも終了処理
Sub IEMain_OnQuit()
    Msgbox "終了します"
    WScript.Quit   'スクリプトを途中で抜ける
End Sub

返信2012/03/17 06:16:30

3ken3memoken3memo   2  1.1 VBScriptを使って JRA IPAT の ページを表示する

あまり使っていないのですが、

VBScriptを使って JRA IPAT の ページを表示してみます。

※OS:Windows 7 だけでExcel無し、Officeは無料のオープンオフィス?の読者から質問が来たので、VBSでIE起動のテストをしてみました。

IEを表示して、INET-IDをセットする

test.vbs

    Dim objIE  '変数を定義します。
    Set objIE = CreateObject("InternetExplorer.Application") 'オブジェクトを作成します。
    objIE.Visible = True      '可視、Trueで見えるようにします。
    
'処理したいページを表示します。
    objIE.Navigate "http://www.ipat.jra.go.jp/"

'ページの表示完了を待ちます。
    While objIE.ReadyState <> 4 Or objIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend
    
'INET-ID(name=inetid)にセットする。
    objIE.Document.getElementsByName("inetid")(0).Value = "S999999PC"

↑のソースを拡張子が.vbsのファイルを作成して保存実行してください。

IEの起動

    Dim objIE  '変数を定義します。
    Set objIE = CreateObject("InternetExplorer.Application") 'オブジェクトを作成します。
    objIE.Visible = True      '可視、Trueで見えるようにします。

表示待ち

'ページの表示完了を待ちます。
    While objIE.ReadyState <> 4 Or objIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend

データのセット

input type="text" name="inetid" に データをセットする。

'INET-ID(name=inetid)にセットする。
    objIE.Document.getElementsByName("inetid")(0).Value = "S999999PC"

いつものテスト動画

テスト結果と作成過程の動画 http://www.youtube.com/watch?v=Ojq1Xp-fKRI です

終わりのあいさつ

いつもサンプルはExcelで作成していたのですが、

Excelが入っていない、OSだけWindowsの読者から質問が来たので、少しイタズラしてみました。

※なかなか、メモ帳でソースコードを打ち込むのは大変でした。

※※よいテキストエディターも探して、紹介しないとなぁ・・・

IE処理の解説は

三流君VBAでIE操作 InternetExplorer.Applicationを操作する

三流解説 VBA IE JRA IPATのページから単勝の表を取り込む サンプルプログラム

記事一覧 - 三流君 ken3のmemo置き場

WebBrowserに関するken3memoのはてなブックマーク

三流解説 VBA IE プロパティの一覧

三流解説 VBA IE メソッドの一覧

三流解説 VBA IE イベントの一覧

など で 細々解説しています。お時間のある時にのぞきにきてください。

返信2012/03/17 05:36:21

4ken3memoken3memo   2  1.2 VBScriptを使って ログインボタンを探して押す JRA IPAT .getElementsByTagNameを使用

まぁ、パターン的に、

.getElementsByTagName("INPUT")

などで、タグを探して、.Clickするそんな感じかなぁ。

a href="#" OnClick="javascript:send();return false;" title="ログイン"> </a</pp>

上記Aのタグを探してクリックしたかったので、

.getElementsByTagName("A")でタグを集めてから、

.Title = "ログイン" を 探して、クリックしてみました。

    Dim objIE  '変数を定義します。
    Set objIE = CreateObject("InternetExplorer.Application") 'オブジェクトを作成します。
    objIE.Visible = True      '可視、Trueで見えるようにします。
    
'処理したいページを表示します。
    objIE.Navigate "http://www.ipat.jra.go.jp/"

'ページの表示完了を待ちます。
    While objIE.ReadyState <> 4 Or objIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend
    
'INET-ID(name=inetid)にセットする。
    objIE.Document.getElementsByName("inetid")(0).Value = "S999999PC"

'ログインボタンを探して押す
    'Aのタグを集める
    Set objA = objIE.Document.getElementsByTagName("A")

    'ループで頭からタイトルがログインを探す
    For n = 0 To objA.Length - 1
        If objA(n).Title = "ログイン" then
            objA(n).Click  '見つけたAタグのオブジェクトをクリック
            Exit For
        End If
    Next

いつものテスト動画

テスト結果と作成過程の動画 http://www.youtube.com/watch?v=iFssuPHfBkw です

IE処理の解説は

三流君VBAでIE操作 InternetExplorer.Applicationを操作する

三流解説 VBA IE JRA IPATのページから単勝の表を取り込む サンプルプログラム

記事一覧 - 三流君 ken3のmemo置き場

WebBrowserに関するken3memoのはてなブックマーク

三流解説 VBA IE プロパティの一覧

三流解説 VBA IE メソッドの一覧

三流解説 VBA IE イベントの一覧

など で 細々解説しています。お時間のある時にのぞきにきてください。

返信2012/03/17 05:42:00

5ken3memoken3memo   4  蛇足 脱線 横道 VBScript IE操作 で javaScriptを実行 Document.Script.setTimeoutをテスト

よく、私の例だと、リンクやボタンのオブジェクトを探して

.Clickで押したように動作させていますが、

javaScriptを直接使っているようなサンプルを最近(前に)見かけました。

下記 はてな人力検索の回答、

VBAでHTMLのページ内でJavaScriptのConfirm関数で表示されるメッセージのボタンを自動的にクリックするには

http://q.hatena.ne.jp/1248657374

で見つけた、

objIE.Document.Script.setTimeout "javascript:document.getElementById('popOK').click()", 200

が、いい感じで使えそうです。

前回の

a href="#" OnClick="javascript:send();return false;" title="ログイン"

の場合だったら、

objIE.Document.Script.setTimeout "javascript:send();return false;", 200

みたいに書くと、

直接プログラム内で、HTML上のjavascriptの関数をコール可能で、

いつもみたいに探してから.Clickよりも、簡単かもしれません。

(※いつもみたいに探すには→ http://d.hatena.ne.jp/ken3memo/20110626/1309072419 をみてください)

場面によって使い分けてください。

ログイン処理のjavascriptを直接起動

a href="#" OnClick="javascript:send();return false;" title="ログイン"

ログインボタンを押すと、

onClick

が走る

だったら、ボタンなんか押さないで、OnClickの内容をそのまま実行すればいいのでは?

ってことで、

.Script.setTimeout "javascript:send();return false;", 200

で、そのまま素直に使ってみた。

    Dim objIE  '変数を定義します。
    Set objIE = CreateObject("InternetExplorer.Application") 'オブジェクトを作成します。
    objIE.Visible = True      '可視、Trueで見えるようにします。
    
'処理したいページを表示します。
    objIE.Navigate "http://www.ipat.jra.go.jp/"

'ページの表示完了を待ちます。
    While objIE.ReadyState <> 4 Or objIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend
    
'INET-ID(name=inetid)にセットする。
    objIE.Document.getElementsByName("inetid")(0).Value = "S999999PC"

'ログインボタンの処理を実行する
    objIE.Document.Script.setTimeout "javascript:send();return false;", 200

いつものテスト動画

テスト結果と作成過程の動画 http://www.youtube.com/watch?v=vzxBNfZDqUU です

↑、こんな感じで、直接コードを呼んだ方が簡単な場合もあったり。

※.Script.setTimeout で 実行ってのが、なんだかなぁ、三流プログラマーの私にもわかるような .Script.Run と .Runみたいなメソッドやコール方法だともっと早く気がついたのに(ははは、たぶん気がつかないか...負け惜しみです)



関連リンク?:

IE処理の解説は

三流君VBAでIE操作 InternetExplorer.Applicationを操作する

三流解説 VBA IE JRA IPATのページから単勝の表を取り込む サンプルプログラム

記事一覧 - 三流君 ken3のmemo置き場

WebBrowserに関するken3memoのはてなブックマーク

三流解説 VBA IE プロパティの一覧

三流解説 VBA IE メソッドの一覧

三流解説 VBA IE イベントの一覧

など で 細々解説しています。お時間のある時にのぞきにきてください。

返信2012/03/17 05:44:07

6ken3memoken3memo   2  1.3 JRA IPAT 時間外の判断 を .getElementsByNameと.Lengthで行う

時間外でログイン画面が出ていない時のエラー処理

.getElementsByName("id or name") で オブジェクトを取得すると、

.Length で 取得したオブジェクト(エレメント)の数がわかるので、

下記のようにして、チェックしてみました。

'INET-ID(name=inetid)にセットする。
    Set objINETID = objIE.Document.getElementsByName("inetid") '変数に一度セットする

    If objINETID.Length = 0 Then  '.Lengthで 取得したエレメントの数がわかります
        '終了処理/エラー処理 0の時は見つからなかったので 
        Msgbox "時間外です。 時間と表示されている場所を確認してください"
        WScript.Quit   'スクリプトを途中で抜ける
    End If

    objINETID(0).Value = "Ken3 TEST"  'データをセットする

.getElementsByNameで一度変数に入れる

直接

objIE.Document.getElementsByName("名前")(0).Value = "値 XXXXX"

みたいに使用しないで、

Set 変数 = objIE.Document.getElementsByName("名前")

で、一度変数にセットする。

Set objINETID = objIE.Document.getElementsByName("inetid") '変数に一度セットする

.Lengthで 取得したエレメントの数 結果を調べ、判断する

.Lengthで数がわかるので、

If objINETID.Length = 0 Then

みたいに、チェック可能となる。

実際の値を入れる時は 変数(0) などで

実際に値をセットしたり、使う時は、

objIE.Document.getElementsByName("inetid")(0).Value = "S999999PC"

ともう一度書いてもいいのですが、

せっかく変数に入れたので、

objINETID(0).Value = "S999999PC" 'データをセットする

と、(0)を使用して、値をセットします。

処理を追加したソース

test.vbs

    Dim objIE  '変数を定義します。
    Set objIE = CreateObject("InternetExplorer.Application") 'オブジェクトを作成します。
    objIE.Visible = True      '可視、Trueで見えるようにします。
    
'処理したいページを表示します。
    objIE.Navigate "http://www.google.co.jp/"

'ページの表示完了を待ちます。
    While objIE.ReadyState <> 4 Or objIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend
    
'INET-ID(name=inetid)にセットする。
    Set objINETID = objIE.Document.getElementsByName("inetid") '変数に一度セットする

    If objINETID.Length = 0 Then  '.Lengthで 取得したエレメントの数がわかります
        '終了処理/エラー処理 0の時は見つからなかったので 
        Msgbox "時間外です。 時間と表示されている場所を確認してください"
        WScript.Quit   'スクリプトを途中で抜ける
    End If

    objINETID(0).Value = "Ken3 TEST"  'データをセットする

'ログインボタンを探して押す
    'Aのタグを集める
    Set objA = objIE.Document.getElementsByTagName("A")

    'ループで頭からタイトルがログインを探す
    For n = 0 To objA.Length - 1
        If objA(n).Title = "ログイン" then
            objA(n).Click  '見つけたAタグのオブジェクトをクリック
            Exit For
        End If
    Next

↑、あっ、あらためて説明しないでも、

.getElementsByTagName("A")

で、前回から使っていたか(笑)

試行錯誤の動画

いつもの試行錯誤のテスト動画です。 http://www.youtube.com/watch?v=oI3R2h7GGS4


関連リンク?:

IE処理の解説は

三流君VBAでIE操作 InternetExplorer.Applicationを操作する

三流解説 VBA IE JRA IPATのページから単勝の表を取り込む サンプルプログラム

記事一覧 - 三流君 ken3のmemo置き場

WebBrowserに関するken3memoのはてなブックマーク

三流解説 VBA IE プロパティの一覧

三流解説 VBA IE メソッドの一覧

三流解説 VBA IE イベントの一覧

など で 細々解説しています。お時間のある時にのぞきにきてください。

返信2012/03/17 05:49:06

7ken3memoken3memo   2  1.4 JRA IPATログインを例題に VBS で 新しいウインドウの処理を実験

JRA IPATのログイン処理で、INET-ID入力後、ログインボタンを押すと、

新しいウインドウ(IE)が立ち上がるので、

あたらしいIEを取得後、データをセットしてみます。

解説の動画 http://www.youtube.com/watch?v=jqbCQEh37PI を見てください。

0:00~ 新しいウインドウ(IE)を変数に取得する

'シェルのオブジェクトを作成後、一番後ろを取り出す

Set objShell = WScript.CreateObject("Shell.Application")

Set objNewIE = objShell.Windows(objShell.Windows.Count - 1) '最後のウインドウと決めつけセット

Set objShell = Nothing 'オブジェクト変数解放

で、手抜きで作ってみました。

3:07~ 値をセットする

新しいウインドウを(objNewIEに)取得したら、

データをセットします

'名前が i,p,r にそれぞれセットする。 セットする場所が objNewIEに注意

objNewIE.Document.forms("FORM1").Item("i").Value = strK_No '加入者番号

objNewIE.Document.forms("FORM2").Item("p").Value = strPassword '暗証番号

objNewIE.Document.forms("FORM3").Item("r").Value = strP_ARS 'P-ARS

↑ソースを表示して、Form1,2,3で区切られていたので、素直に

オブジェクト.Document.forms("フォーム名").Item("項目名").Value = で 値をセットしました。

5:56 ~ IPATメニューへ を クリックする

値をセットしたら

a href="#" onClick="JavaScript:Chk();return false;" title="IPATメニューへ"> </a</pp>

をクリックしたいので、

title="IPATメニューへ"を判断材料にして、同じように

'Aのタグを集める

Set objA = objIE.Document.getElementsByTagName("A")

'ループで頭からタイトルがログインを探す

For n = 0 To objA.Length - 1

If objA(n).Title = "IPATメニューへ" then

objA(n).Click '見つけたAタグのオブジェクトをクリック

Exit For

End If

Next

Set objA = Nothing 'オブジェクト変数解放


完成したソース

xxxx.vbs など、.vbsで保存して、使ってみてください。

'頭で固定値をセットする 自分の番号をセットする。
strINET_ID  = "S999999PC"   'INET-ID
strP_ARS    = "0000"      'P-ARS
strK_No     = "60099999"  '加入者番号
strPassword = "1234"      '暗証番号、あまり保存したくないけど

'パスワード保存したくない人向け、頭で入力させる
If strPassword = "" Then
    strPassword = InputBox("暗証番号を入れてください")
End If


'IEの起動

    Dim objNewIE  '新しいIEのオブジェクト

    Dim objIE  '変数を定義します。
    Set objIE = WScript.CreateObject("InternetExplorer.Application", "IEMain_") 'オブジェクト作成
    objIE.Visible = True      '可視、Trueで見えるようにします。
    
'処理したいページを表示します。
    objIE.Navigate "http://www.ipat.jra.go.jp/"

'ページの表示完了を待ちます。
    While objIE.ReadyState <> 4 Or objIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend

'INET-ID(name=inetid)にセットする。
    Set objINETID = objIE.Document.getElementsByName("inetid") '変数に一度セットする

    If objINETID.Length = 0 Then  '.Lengthで 取得したエレメントの数がわかります
        '終了処理/エラー処理 0の時は見つからなかったので 
        Msgbox "時間外です。 時間と表示されている場所を確認してください"
        WScript.Quit   'スクリプトを途中で抜ける
    End If

    objINETID(0).Value = strINET_ID   'データをセットする
    Set objINETID = Nothing  'オブジェクト変数解放

'ログインボタンを探して押す
    'Aのタグを集める
    Set objA = objIE.Document.getElementsByTagName("A")

    'ループで頭からタイトルがログインを探す
    For n = 0 To objA.Length - 1
        If objA(n).Title = "ログイン" then
            objA(n).Click  '見つけたAタグのオブジェクトをクリック
            Exit For
        End If
    Next

    Set objA = Nothing  'オブジェクト変数解放

'手抜きで、ログイン判断で5秒待つ?
WScript.Sleep  5000  '5秒待つ 1000で1秒

'シェルのオブジェクトを作成後、一番後ろを取り出す
Set objShell = WScript.CreateObject("Shell.Application")
Set objNewIE = objShell.Windows(objShell.Windows.Count - 1) '最後のウインドウと決めつけセット
Set objShell = Nothing  'オブジェクト変数解放

'ページの表示完了を待ちます。
    While objNewIE.ReadyState <> 4 Or objNewIE.Busy = True '.ReadyState <> 4の間まわる。
        WScript.Sleep  100  '0.1秒待つ 1000で1秒
    Wend

'新しく開いたIEに値をセットする
    'エラー画面か?項目名iの数でチェックする
    Set objI = objNewIE.Document.getElementsByName("i") '変数に一度セットする
    If objI.Length = 0 Then  '.Lengthで 取得したエレメントの数がわかります
        '終了処理/エラー処理 0の時は見つからなかったので 
        Msgbox "INET-IDがエラーです確認してください。"
        objNewIE.Quit  '新しく開いたIEを閉じる
        objIE.Quit     '元のIEも閉じる
        WScript.Quit   'スクリプトを途中で強制終了
    End If
    Set objI = Nothing

    '名前が i,p,r にそれぞれセットする。 セットする場所が objNewIEに注意
    objNewIE.Document.forms("FORM1").Item("i").Value = strK_No '加入者番号
    objNewIE.Document.forms("FORM2").Item("p").Value = strPassword '暗証番号
    objNewIE.Document.forms("FORM3").Item("r").Value = strP_ARS  'P-ARS
    '↑同じ名称が使われているので、forms("FORM1"),2,3を指定しました。

'IPATメニューへ を クリックする
    'Aのタグを集める
    Set objA = objNewIE.Document.getElementsByTagName("A")

    'ループで頭からタイトルがログインを探す
    For n = 0 To objA.Length - 1
        If objA(n).Title = "IPATメニューへ" then
            objA(n).Click  '見つけたAタグのオブジェクトをクリック
            Exit For
        End If
    Next

    Set objA = Nothing  'オブジェクト変数解放

msgbox "ログイン スクリプト 終了 "

'ここから、データ取得や投票を行う、そんなスクリプトを書く

WScript.Quit   'スクリプトを終了

'------------------------------------------------
'元IE(のイベント処理)
'スクリプトも終了処理
Sub IEMain_OnQuit()
    Msgbox "終了します"
    WScript.Quit   'スクリプトを途中で抜ける
End Sub

'ウインドウを開く前のアクション
Sub IEMain_BeforeNavigate2(ByVal pDisp, URL, Flags, TargetFrameName, PostData, Headers, Cancel)

End Sub

'本当は、こっちで取得したかったけど・・・
Sub IEMain_NewWindow2(ppDisp, Cancel)

End Sub

終わりのあいさつ

今回も、コピペ(コピー貼りつけ)プログラムで失敗したけど、温かい目で見てください。

あとは、データ収集と実際の購入 サンプルですね。

先は長いかなぁ・・・・


関連リンク?:

IE処理の解説は

三流君VBAでIE操作 InternetExplorer.Applicationを操作する

三流解説 VBA IE JRA IPATのページから単勝の表を取り込む サンプルプログラム

記事一覧 - 三流君 ken3のmemo置き場

WebBrowserに関するken3memoのはてなブックマーク

三流解説 VBA IE プロパティの一覧

三流解説 VBA IE メソッドの一覧

三流解説 VBA IE イベントの一覧

など で 細々解説しています。お時間のある時にのぞきにきてください。

返信2012/03/17 05:51:52









    三流君 www.ken3.org(手打ちのHTMLで情報発信、最近は更新してなかったり...) 分類:HPを大きく分けると4つの柱(分類)です。
    ・人気は[VBA,マクロ]の解説、VBAからIE操作が人気です
    ・一昔前の[ASP(Active Server Pages)]の解説。
    ・読み物として[プログラマーの愚痴]では、あまり見せたくない三流プログラマーの内面かな。
    ・おまけで[元コンビニ店長時代の話]が弟に巻き込まれ、失敗した脱サラ、畑違い?の異業種へ転職、コンビニ店長で失敗。

    動画・YouTube(動画で解説に手を出してみたが、評判はイマイチ...内容に問題アリ?)
    ・YouTube [ken3video] え~と、こんな感じ...の独り言が多い解説やテストの動画です。

    流行のBlogで情報発信(手打ちのHTMLよりブログで更新が楽なので)
    ・はてなを使用して[id:ken3memo]メモ的に放り込んでいるブログです
    ・[その他商品紹介Blog] ・・・ 内容の薄い、商品のメモ?です



    トップ ユーザー登録 ログイン ヘルプ